TIA博图软件SCL程序编写和LAD程序编写对照案例（二）

>

例子：

交通红绿灯

设计交通红绿灯PLC控制系统，控制要求：

1）东西向：绿灯（QO.5）亮5秒，绿灯闪3次（灭0.5秒亮0.5秒），黄灯(Q0.4)亮2秒，红灯亮(Q0.3)10秒。

2）南北向：红灯亮(Q0.0)10秒，绿灯亮5秒，绿灯(Q0.2)闪3次，黄灯(Q0.1)亮2秒。

3）按下I0.0启动正常运行，按下I0.1等待整个过程停止后双向黄灯闪烁。

SCL流程写法：

//启/停

#R_TRIG_Instance(CLK:=#启动);

IF #R_TRIG_Instance.Q AND #流程 = 0 THEN

#流程 := 1;

#闪标志 := 0;

#南北黄灯 := #东西黄灯 := 0;

END_IF;

#R_TRIG_Instance_1(CLK:=#停止);

IF #R_TRIG_Instance_1.Q THEN

#停止标志 := 1;

END_IF;

//东西绿灯亮5s

IF #流程 = 1 THEN

#东西绿灯 := #南北红灯 := 1;

END_IF;

#T0(IN:=#流程 = 1,

PT:=T#5S);

IF #T0.Q THEN

#流程 := 2;

END_IF;

//东西绿灯闪3次

IF #流程 = 2 THEN

#东西绿灯 := 0;

END_IF;

#T1(IN:=#流程 = 2,

PT:=T#0.5S);

IF #T1.Q THEN

#东西绿灯 := 1;

END_IF;

#T2(IN:=#T1.Q,

PT:=T#0.5S);

IF #T2.Q THEN

RESET_TIMER(#T1);

#东西绿灯闪3次 += 1;

END_IF;

IF #东西绿灯闪3次>=3 THEN

#流程 := 3;

#东西绿灯 := 0;

#东西绿灯闪3次 := 0;

END_IF;

//东西黄灯亮2s

IF #流程 = 3 THEN

#东西黄灯 := 1;

END_IF;

#T3(IN:=#流程 = 3,

PT:=T#2S);

IF #T3.Q THEN

#东西黄灯 := 0;

#南北红灯 := 0;

#流程 := 4;

END_IF;

//南北绿灯亮5s

IF #流程 = 4 THEN

#南北绿灯 := #东西红灯 := 1;

END_IF;

#T4(IN := #流程 = 4,

PT := T#5S);

IF #T4.Q THEN

#流程 := 5;

END_IF;

//南北绿灯闪3次

IF #流程 = 5 THEN

#南北绿灯 := 0;

END_IF;

#T5(IN := #流程 = 5,

PT := T#0.5S);

IF #T5.Q THEN

#南北绿灯 := 1;

END_IF;

#T6(IN := #T5.Q,

PT := T#0.5S);

IF #T6.Q THEN

RESET_TIMER(#T5);

#南北绿灯闪3次 += 1;

END_IF;

IF #南北绿灯闪3次 >= 3 THEN

#流程 := 6;

#南北绿灯 := 0;

#南北绿灯闪3次 := 0;

END_IF;

//南北黄灯亮2s

IF #流程 = 6 THEN

#南北黄灯 := 1;

END_IF;

#T7(IN := #流程 = 6,

PT := T#2S);

IF #T7.Q THEN

#南北黄灯 := 0;

#东西红灯 := 0;

#流程 := 7;

END_IF;

////循环OR 停止

IF #流程 = 7 AND NOT #停止标志 THEN

#流程 := 1;

END_IF;

IF #流程 = 7 AND #停止标志 THEN

#流程 := 0;

#停止标志 := 0;

#闪标志 := 1;

END_IF;

//双向黄灯闪烁

IF #闪标志 THEN

#南北黄灯 := #东西黄灯 := 1;

END_IF;

#T8(IN:=#闪标志,

PT:=T#0.5S);

IF #T8.Q THEN

#南北黄灯 := #东西黄灯 := 0;

END_IF;

#T9(IN:=#T8.Q,

PT:=T#0.5S);

IF #T9.Q THEN

RESET_TIMER(#T8);

END_IF;

SCL语言比较指令写法：

#R_TRIG_Instance(CLK:=#启动);

IF #R_TRIG_Instance.Q AND NOT #启动标志 THEN

#启动标志 := 1;

#双黄闪标志 := 0;

#停止 := 0;

END_IF;

#R_TRIG_Instance_1(CLK:=#停止);

IF #R_TRIG_Instance_1.Q THEN

#停止标志 := 1;

#启动 := 0;

END_IF;

#T0(IN:=#启动标志,

PT:=T#20S);

#南北红灯 := T#0S < #T0.ET AND #T0.ET <= T#10S;

#东西红灯 := T#10S < #T0.ET AND #T0.ET <= T#20S;

#东西绿灯 := (T#0S < #T0.ET AND #T0.ET <= T#5S)

OR (T#5.5S < #T0.ET AND #T0.ET <= T#6S)

OR (T#6.5S < #T0.ET AND #T0.ET <= T#7S)

OR (T#7.5S < #T0.ET AND #T0.ET <= T#8S);

#南北绿灯 := (T#10S < #T0.ET AND #T0.ET <= T#15S)

OR (T#15.5S < #T0.ET AND #T0.ET <= T#16S)

OR (T#16.5S < #T0.ET AND #T0.ET <= T#17S)

OR (T#17.5S < #T0.ET AND #T0.ET <= T#18S);

#东西黄灯 := (T#8S < #T0.ET AND #T0.ET <= T#10S)

OR (T#0.5S < #T1.ET AND #T1.ET <= T#1S);

#南北黄灯 := (T#18S < #T0.ET AND #T0.ET <= T#20S)

OR (T#0.5S < #T1.ET AND #T1.ET <= T#1S);

IF #T0.Q AND NOT #停止标志 THEN

RESET_TIMER(#T0);

END_IF;

IF #T0.Q AND #停止标志 THEN

#启动标志 := 0;

#停止标志 := 0;

#双黄闪标志 := 1;

END_IF;

#T1(IN:=#双黄闪标志,

PT:=T#1S);

IF #T1.Q THEN

RESET_TIMER(#T1);

END_IF;

梯形图LAD写法：

综上所述，不管是用SCL编写还用LAD编写，程序逻辑都一样，编写方式大同小异！

END

点点在看给小编加个鸡腿

免责声明：如果侵犯了您的权益，请联系站长，我们会及时删除侵权内容，谢谢合作！